'rename this file to WindowsHotkeyRepair.vbs
'then double click it to run

'from http://niveauverleih.blogspot.com

'This script frees up a blocked hotkey combination
'Windows Hotkeys sometimes become unavailable because the corresponding shortcut has been permanently deleted
'This is a Windows bug
'This script programmatically creates 2 new shortcuts, both with the hotkey in question
'Then it resets the hotkey for the second shortcut
'Then it deletes the 2 shortcuts
'I don't know exactly why it works, but it does work (took me hours to figure it out)

Set objShell = CreateObject("WScript.Shell")

strDesktop = objShell.SpecialFolders("Desktop")
strPath =  strDesktop & "\TempShortcut.lnk"
strPath2 =  strDesktop & "\TempShortcut2.lnk"


'some explanation on creating hotkey combinations
'from http://www.devguru.com/technologies/wsh/17425.asp
strExplanation = "Which hotkey combination do you want to repair?" & vbcr & vbcr & _ 
		"The valid modifier key-names are:" & vbcr & _
		"ALT+ CTRL+ SHIFT+ and EXT+." & vbcr & vbcr & _
		"The valid standard keynames are:" & vbcr & _
		"A .. Z, 0 .. 9, Back, Tab, Clear, Return, Escape, Space and Prior." & vbcr & vbcr & _
		"All are case insensitive."

'Ask user for hotkey combination to repair 
strHotkeys = Inputbox (strExplanation,"Windows Hotkey Repair","CTRL+SHIFT+N")

If strHotkeys = "" Then wscript.quit

'create first shortcut and assign hotkeys
Set objShtCut = objShell.CreateShortcut (strPath)
objShtCut.HotKey = strHotkeys
objShtCut.Save()

'create second shortcut and assign the same hotkeys
Set objShtCut2 = objShell.CreateShortcut (strPath2)
objShtCut2.HotKey = strHotkeys
objShtCut2.Save()

'reset hotkeys of second shortcut 
Set objShtCut2 = objShell.CreateShortcut (strPath2)
objShtCut2.HotKey = ""
objShtCut2.Save()

'delete both shortcuts
Set filesys = CreateObject("Scripting.FileSystemObject") 
filesys.DeleteFile strPath
filesys.DeleteFile strPath2

msgbox "You can know reassign the hotkey combination " & strHotkeys