Visual Basic 2012 Voorbeelden
   

visual basic 2012 broncode voorbeelden

Blijf op de hoogte van de recente aanpassingen op vbvoorbeelden!

Microsoft Visual Studio 2012Microsoft Developers Network - Visual BasicMicrosoft .NET Framework

29.7. XML Benaderen via Axis Properties - Descendant Axis

Print Email Deel op Twitter Deel op Facebook

Dit artikel is gepubliceerd op maandag 15 oktober 2012 op vbvoorbeelden, bezoek de website voor een recente versie van dit artikel of andere artikels.

Via de Descendants functie met XName argument kunnen we alle nakomeling elementen van een XContainer bekomen die een bepaalde naam hebben.

Een alternatief hiervoor is de "descendant axis" notatie, deze is gelijkaardig aan de child axis notatie, maar de "dot" wordt hierin vervangen door drie dots :
Visual Basic 2012 Broncode - Codevoorbeeld 760
Option Explicit On
Option Strict On

Imports System.Collections.Generic
Imports System.Xml.Linq

Namespace AccessingXMLAxisProperties
    Class DescendantAxisExample
        Public Shared Sub Main()
            Dim document As XDocument = <?xml version="1.0"?>
                                        <departement>
                                            <name>Sales</name>
                                            <employee>
                                                <id>123</id>
                                                <name>John Smith</name>
                                            </employee>
                                            <employee>
                                                <id>456</id>
                                                <name>Jane Jones</name>
                                            </employee>
                                        </departement>
            '
            Dim names As IEnumerable(Of XElement)
            '
            names = document.Descendants(XName.Get("name"))
            Print(names)
            '
            names = document...<name>
            Print(names)
            '
            Console.ReadLine()
        End Sub
        Public Shared Sub Print(ByVal elements As IEnumerable(Of XElement))
            For Each element As XElement In elements
                Console.WriteLine(element.ToString())
            Next
            Console.WriteLine()
        End Sub
    End Class
End Namespace
Console Application Output
<name>Sales</name>
<name>John Smith</name>
<name>Jane Jones</name>

<name>Sales</name>
<name>John Smith</name>
<name>Jane Jones</name>
Bemerk dat we in bovenstaand voorbeeld werken met een XDocument, want ook deze zijn XContainers waarop we deze mogelijkheden hebben.

Dit artikel is gepubliceerd op maandag 15 oktober 2012 op vbvoorbeelden, bezoek de website voor een recente versie van dit artikel of andere artikels.