Visual Basic 2012 Voorbeelden
   

visual basic 2012 broncode voorbeelden

Blijf op de hoogte van de recente aanpassingen op vbvoorbeelden!

Microsoft Visual Studio 2012Microsoft Developers Network - Visual BasicMicrosoft .NET Framework

29.6. XML Benaderen via Axis Properties - Child Axis

Print Email Deel op Twitter Deel op Facebook

Dit artikel is gepubliceerd op maandag 15 oktober 2012 op vbvoorbeelden, bezoek de website voor een recente versie van dit artikel of andere artikels.

Axis properties, die een vrij specifieke synthax hebben, kan men gebruiken om op eenvoudige wijze elementen en attributen te benaderen.
In dergelijk notatie gebruikt men de naam van het element of attribute om deze te adresseren.

Om alle child elements (XElements) met een bepaalde naam van een XContainer te bekomen kan men de Elements functie gebruiken waaraan men een XName parameter doorgeeft.

Een alternatief hiervoor is de "child axis" notatie, hier laat je de object expressie volgen door de letterlijke node met die naam zoals de child elementen die je als resultaat wenst.
Bijvoorbeeld someContainer.<xyz> zal van het XContainer object in IEnumerable(Of XElement) vorm alle child elementen met naam xyz opleveren.

Een voorbeeld :
Visual Basic 2012 Broncode - Codevoorbeeld 759
Option Explicit On
Option Strict On

Imports System.Collections.Generic
Imports System.Xml.Linq

Namespace AccessingXMLAxisProperties
    Class ChildAxisExample
        Public Shared Sub Main()
            Dim employeeXElement As XElement = _
                <employee>
                    <name>John Smith</name>
                    <departement type="Sales">London</departement>
                    <departement type="distribution">England</departement>
                </employee>
            '
            Dim departements As IEnumerable(Of XElement)
            '
            departements = employeeXElement.Elements(XName.Get("departement"))
            Print(departements)
            '
            departements = employeeXElement.<departement>
            Print(departements)
            '
            Console.ReadLine()
        End Sub
        Public Shared Sub Print(ByVal elements As IEnumerable(Of XElement))
            For Each element As XElement In elements
                Console.WriteLine(element.ToString())
            Next
            Console.WriteLine()
        End Sub
    End Class
End Namespace
Console Application Output
<departement type="Sales">London</departement>
<departement type="distribution">England</departement>

<departement type="Sales">London</departement>
<departement type="distribution">England</departement>

Dit artikel is gepubliceerd op maandag 15 oktober 2012 op vbvoorbeelden, bezoek de website voor een recente versie van dit artikel of andere artikels.