Visual Basic 2012 Voorbeelden
   

visual basic 2012 broncode voorbeelden

Blijf op de hoogte van de recente aanpassingen op vbvoorbeelden!

Microsoft Visual Studio 2012Microsoft Developers Network - Visual BasicMicrosoft .NET Framework

29.10. XML Benaderen via Axis Properties - Attribute Axis

Print Email Deel op Twitter Deel op Facebook

Dit artikel is gepubliceerd op maandag 15 oktober 2012 op vbvoorbeelden, bezoek de website voor een recente versie van dit artikel of andere artikels.

Ook om attributen te benaderen kan men een axis notatie gebruiken, in dit geval iets wat men "attribute axis" noemt.
In deze notatie laat men de dot volgen door een @ en de naam van het attribuut waarvan je de waarde wenst op te halen.

Dit kan uiteraard ook via de Attribute method waaraan je een XName parameter doorgeeft.  Maar zoals je in onderstaand voorbeeld ziet, is dat een stuk complexer :
Visual Basic 2012 Broncode - Codevoorbeeld 763
Option Explicit On
Option Strict On

Imports System.Xml.Linq

Namespace AccessingXMLAxisProperties
    Class AttributeAxisExample
        Public Shared Sub Main()
            Dim departement As XElement = _
                                 <departement type="Sales">London</departement>
            Dim departementTypeAttributeValue As String
            '
            departementTypeAttributeValue = _
                                 departement.Attribute(XName.Get("type")).Value
            Console.WriteLine(departementTypeAttributeValue)
            '
            departementTypeAttributeValue = departement.@type
            Console.WriteLine(departementTypeAttributeValue)
            '
            Console.ReadLine()
        End Sub
    End Class
End Namespace
Console Application Output
Sales
Sales
In onderstaand voorbeeld combineren we het gebruik van attribute axis met een LINQ query om een nieuw <departements> XElement op te bouwen met daarin <departement> child elementen voor alle mogelijke waardes voor het attribuut type die gevonden worden in alle <departement> nakomelingen van het <employees> XElement object :
Visual Basic 2012 Broncode - Codevoorbeeld 764
Namespace AccessingXMLAxisProperties
    Class CombinedExample1
        Public Shared Sub Main()
            Dim employees As XElement = _
                <employees>
                    <employee>
                        <name>Alex Smith</name>
                    </employee>
                    <employee>
                        <name>John Smith</name>
                        <departement type="Sales">London</departement>
                        <departement type="Distribution">England</departement>
                    </employee>
                    <employee>
                        <name>Jane Jones</name>
                        <departement type="Management">Manchester</departement>
                    </employee>
                </employees>
            '
            Dim departementTypes As XElement = _
            <departementTypes>
                <%= _
                    From departement In employees...<departement> _
                    Select <departement><%= departement.@type %></departement> _
                %>
            </departementTypes>
            Console.WriteLine(departementTypes.ToString())
            '
            Console.ReadLine()
        End Sub
    End Class
End Namespace
Console Application Output
<departementTypes>
  <departement>Sales</departement>
  <departement>Distribution</departement>
  <departement>Management</departement>
</departementTypes>

Dit artikel is gepubliceerd op maandag 15 oktober 2012 op vbvoorbeelden, bezoek de website voor een recente versie van dit artikel of andere artikels.