Visual Basic 2012 Voorbeelden
   

visual basic 2012 broncode voorbeelden

Blijf op de hoogte van de recente aanpassingen op vbvoorbeelden!

Microsoft Visual Studio 2012Microsoft Developers Network - Visual BasicMicrosoft .NET Framework

16.1. String Datatype

Print Email Deel op Twitter Deel op Facebook

Dit artikel is gepubliceerd op maandag 15 oktober 2012 op vbvoorbeelden, bezoek de website voor een recente versie van dit artikel of andere artikels.

Hieronder zie je enkele voorbeelden van het gebruik van members uit de System.String klasse om enkel standaard bewerkingen uit te voeren :
Visual Basic 2012 Broncode - Codevoorbeeld 416
Option Explicit On
Option Strict On
Class Example1
    Public Shared Sub Main()
        Dim text As String = "visual basic .net"
        '
        ' retrieving 'String'-information :
        Console.WriteLine(text.Length)               ' 17
        Console.WriteLine(text.Chars(7))             ' "b"c
        '
        ' 'String'-concatenations / -paddings / -insertions :
        Console.WriteLine(String.Concat("course ", text))
        '                                             "course visual basic .net"
        Console.WriteLine(text.PadLeft(30))
        '                                       "             visual basic .net"
        Console.WriteLine(text.PadRight(30, "."c))
        '                                       "visual basic .net............."
        Console.WriteLine(text.Insert(13, "language "))
        '                                           "visual basic language .net"
        '
        ' substringing 'String's :
        Console.WriteLine(text.Substring(13))        ' ".net"
        Console.WriteLine(text.Substring(7, 5))      ' "basic"
        '
        ' clearing 'String's :
        Console.WriteLine(text.Remove(7, 6))         ' "visual .net"
        '
        text = String.Concat("  ", text, "     ")
        ' trimming 'String's :
        Console.WriteLine(text.Trim())               ' "visual basic .net"
        Console.WriteLine(text.TrimStart())          ' "visual basic .net     "
        Console.WriteLine(text.TrimEnd())            ' "  visual basic .net"
        Console.WriteLine(text.Trim(New Char() {" "c, "v"c, "t"c, "e"c}))
        '                                              "isual basic .n"
        '
        ' replacing 'String's :
        Console.WriteLine(text.Replace("basic", "c#")) ' "visual c# .net"
        '
        text = "Visual Basic .NET"
        ' 'String'-casing :
        Console.WriteLine(text.ToUpper())            ' "VISUAL BASIC .NET"
        Console.WriteLine(text.ToLower())            ' "visual basic .net"
        '
        ' 'String'-searching :
        Console.WriteLine(text.IndexOf("Basic"))     ' 7 (case sensitive)
        Console.WriteLine(text.LastIndexOf("e"c))    ' -1 (case sensitive)
        Console.WriteLine(text.StartsWith("Visual")) ' True (case sensitive)
        Console.WriteLine(text.EndsWith(".Net"))     ' False (case sensitive)
        '
        Console.ReadLine()
    End Sub
End Class
Console Application Output
17
b
course visual basic .net
             visual basic .net
visual basic .net.............
visual basic language .net
.net
basic
visual .net
visual basic .net
visual basic .net
  visual basic .net
isual basic .n
  visual c# .net
VISUAL BASIC .NET
visual basic .net
7
-1
True
False
Alle bovenvermelde methods uitgezonderd String.Concat() zijn instance function methods.  Deze function methods gaan het String object - waarop die method wordt aangeroepen - niet aanpassen, maar zullen het gewijzigde resultaat (hier doorgaans String object) opleveren.

16.1.1. Splitting en Joining Strings

Hieronder zie je enkele voorbeelden van het gebruik van instance- en classmembers uit de String klasse om splitting en joining van strings uit te voeren :
Visual Basic 2012 Broncode - Codevoorbeeld 417
Class Example2
    Public Shared Sub Main()
        Dim text As String = "Visual-Basic .NET."
        '
        ' converting a 'String' to a 'Char' array :
        Dim characters As Char() = text.ToCharArray()
        For Each character As Char In characters
            Console.Write(character & "/")
        Next
        Console.WriteLine()            ' "V/i/s/u/a/l/-/B/a/s/i/c/ /./N/E/T/./"
        characters = text.ToCharArray(7, 5) ' start-index 7, length 5
        For Each character As Char In characters
            Console.Write(character & "/")
        Next
        Console.WriteLine()            ' "B/a/s/i/c/"
        '
        ' splitting a 'String' to a 'Sting' array :
        Dim words As String() = text.Split(" "c)
        For Each woord As String In words
            Console.Write(woord & "/")
        Next
        Console.WriteLine()            ' "Visual-Basic/.NET./"
        words = text.Split(New Char() {" "c, "-"c})
        For Each woord As String In words
            Console.Write(woord & "/")
        Next
        Console.WriteLine()            ' "Visual/Basic/.NET./"
        words = text.Split(New Char() {" "c, "-"c}, 2) ' maximal 2 elements
        For Each woord As String In words
            Console.Write(woord & "/")
        Next
        Console.WriteLine()            ' "Visual/Basic .NET/"
        '
        ' joining a 'Char' array to a 'String' :
        words = text.Split(New Char() {" "c, "-"c})
        Console.WriteLine(String.Join("<space>", words))
        '                                "Visual<space>Basic<space>.NET."
        Console.WriteLine(String.Join("<space>", words, 1, 2))
        '                                start-index 1, length 2
        '                                "Basic<space>.NET."
        '
        Console.ReadLine()
    End Sub
End Class
Console Application Output
V/i/s/u/a/l/-/B/a/s/i/c/ /./N/E/T/./
B/a/s/i/c/
Visual-Basic/.NET./
Visual/Basic/.NET./
Visual/Basic .NET./
Visual<space>Basic<space>.NET.
Basic<space>.NET.

Dit artikel is gepubliceerd op maandag 15 oktober 2012 op vbvoorbeelden, bezoek de website voor een recente versie van dit artikel of andere artikels.