Visual Basic 2012 Voorbeelden
   

visual basic 2012 broncode voorbeelden

Blijf op de hoogte van de recente aanpassingen op vbvoorbeelden!

Microsoft Visual Studio 2012Microsoft Developers Network - Visual BasicMicrosoft .NET Framework

28.3. Regular Expressions - Replacements

Print Email Deel op Twitter Deel op Facebook

Dit artikel is gepubliceerd op maandag 15 oktober 2012 op vbvoorbeelden, bezoek de website voor een recente versie van dit artikel of andere artikels.

De matches in een inputstring kunnen we vervangen aan de hand van de Replace method.  Deze verwacht een "replacementstring", die aangeeft door wat de match vervangen wordt.

Om in de replacementstring te verwijzen naar onderdelen van de match of van de inputstring gebruikt men "substitutions" :

(1) $& stelt de volledige match voor.
(2) $2 of ${2} stelt de capture voor van group met nummer 2.
(3) $+ stelt de capture voor van de laatste group.
(4) ${secondword} stelt de capture voor van group met naam secondword.
(5) $` (backquote) stelt de tekst voor de volledige match voor.
(6) (singlequote) stelt de tekst na de volledige match voor.
(7) $_ (underscore) stelt de volledige inputstring voor.
Visual Basic 2012 Broncode - Codevoorbeeld 702
Imports System.Text.RegularExpressions
Class Example1
    Public Shared Sub Main()
        Dim input As String = "This is an example."
        Dim pattern As String = "(an) (?<secondword>example)"
        Console.WriteLine(Regex.Replace(input, pattern, "$& $&"))          ' (1)
        Console.WriteLine(Regex.Replace(input, pattern, "a first ${2}"))   ' (2)
        Console.WriteLine(Regex.Replace(input, pattern, "a first $+"))     ' (3)
        Console.WriteLine(Regex.Replace(input, pattern, _
                                        "a second ${secondword}"))         ' (4)
        Console.WriteLine(Regex.Replace(input, pattern, _
                             "a first example.  $`a second example"))      ' (5)
        Console.WriteLine(Regex.Replace(input, pattern, "$'$'"))           ' (6)
        Console.WriteLine(Regex.Replace(input, pattern, "$_"))             ' (7)
        '
        Console.ReadLine()
    End Sub
End Class
Console Application Output
This is an example an example.
This is a first example.
This is a first example.
This is a second example.
This is a first example.  This is a second example.
This is ...
This is This is an example..
In dit voorbeeld werd de shared method Replace gebruikt, ook een instance method Replace voor objecten van het type Regex is beschikbaar.

Dit artikel is gepubliceerd op maandag 15 oktober 2012 op vbvoorbeelden, bezoek de website voor een recente versie van dit artikel of andere artikels.