Visual Basic 2012 Voorbeelden
   

visual basic 2012 broncode voorbeelden

Blijf op de hoogte van de recente aanpassingen op vbvoorbeelden!

Microsoft Visual Studio 2012Microsoft Developers Network - Visual BasicMicrosoft .NET Framework

29.4. LINQ Queries als Embedded Expressies

Print Email Deel op Twitter Deel op Facebook

Dit artikel is gepubliceerd op maandag 15 oktober 2012 op vbvoorbeelden, bezoek de website voor een recente versie van dit artikel of andere artikels.

Ook LINQ queries kunnen als embedded expressie worden gebruikt in XML literals om op dynamische wijze de XML data te voeden met informatie.

In onderstaand voorbeeld worden de <departement> child nodes voor de <employee> node samengesteld door de selector in de Select clausule van de LINQ query, die op zijn beurt de informatie voor deze child nodes uit de List(Of Departement) haalt :
Visual Basic 2012 Broncode - Codevoorbeeld 756
Option Explicit On
Option Strict On

Imports System.Linq

Namespace CreatingXML
    Class LINQQueryInXMLLiteralExample
        Public Shared Sub Main()
            Dim departements As New List(Of Departement)
            departements.Add(New Departement With {.Area = "London", _
                                                 .Type = DepartementType.Sales})
            departements.Add(New Departement With {.Area = "England", _
                                          .Type = DepartementType.Distrubution})
            '
            Dim employee1 As XElement = _
                                <employee>
                                    <name>John Smith</name>
                                    <%= From d In departements _
                                        Select <departement type=<%= d.Type %>>
                                                   <%= d.Area %>
                                               </departement> %>
                                </employee>
            Console.WriteLine(employee1.ToString())
            '
            Console.ReadLine()
        End Sub
    End Class
    Class Departement
        Public Property Area As String
        Public Property Type As DepartementType
    End Class
    Enum DepartementType
        Sales
        Distrubution
    End Enum
End Namespace
Console Application Output
<employee>
  <name>John Smith</name>
  <departement type="Sales">London</departement>
  <departement type="Distrubution">England</departement>
</employee>
De LINQ query uit bovenstaand voorbeeld levert hier een collectie op van XElement objecten.

Dit artikel is gepubliceerd op maandag 15 oktober 2012 op vbvoorbeelden, bezoek de website voor een recente versie van dit artikel of andere artikels.