<-Back

Class E RF Amplifier experiments

NEW for Dec. 2009: Class E design notes!!!!!! Easy formulas to get you started are found here...

New for May 2010: Some detailed notes on the derivation of the formulas for Class-E design.

Related to the HF Tesla coil work, the Class-E RF power amplifier seeks to maximise the efficiency of the amplifier by optimising the times when the amplifier switching element turns on or off. By using a low-Q resonant network in the drain circuit, we can take advantage of “ringing” by switching the transistor when the drain-source voltage is at a minimum.

This project starts with a modified form of the circuit given in J. F. Davis and D. B. Rutledge, “A low-cost class-E power amplifier with sine-wave drive,” IEEE MTT-S Int. Microwave Symp. Dig., vol. 2, pp. 1113-1116, Jun. 1998. This paper is a good starting point for learning about this amplifier type.

The schematic of my modified version is designed for use at 4.5MHz. Some of the modifications are to reduce high-frequency ringing that takes place near the switching transients. I have also used my favourite MOSFET: the 2SK2698. Some aspects of the input and output matching are different, given the different transistor impedances. All in all, though, the drain impedance of about 13 ohms reported in Rutledge's paper was nearly spot-on, given the drain current/voltage selected for this example.

Page contents:

  1. Prototypical circuit

  2. Spice Simulations

  3. Prototype construction and testing

  4. References

  5. Spice Code for Simulations



The prototypical circuit

This circuit is modified slightly with the addition of the series resistor-capacitor branch on the left. This helps in reducing VHF ringing in the gate circuit. I have also included a reverse diode to ground in the drain circuit to help the internal avalanche diode to reduce undershoot.


The resonant matching network serves the triple purpose of “smoothing” the ragged drain voltage waveform, optimising the impedance match between the load and the transistor drain as well as reducing second-harmonic distortion. Let's look at some SPICE simulations

SPICE simulations of Class-E amplifier

Given a 4.5 MHz signal at the input, we can ''measure'' the voltage at test point TP1:




The smooth sinusoid is the generator waveform. Notice how the gate voltage waveform is rather bumpy and asymmetrical. This type of behaviour seems to be usual and has been reported by Davis and Rutledge (ibid). There are significant high frequency components that appear.

The voltage measured on the drain at TP2, as well as the current through the drain of the MOSFET are


Notice the high negative current spike that appears at transistor turn-on. It is not immediately clear why so much current should flow here but it could be a consequence of the 450pF capacitor discharging residual voltage at the beginning of the turn-on cycle. Most important, we notice that the drain voltage is a small fraction of its peak value when the transistor is switched on or off. This is why the transistor dissipation is so small compared to the total power. Here is where we get the efficiency!



After the resonant matching network, we get a fairly clean sine wave output.




This can be seen from the output spectrum.




The second harmonic is well suppressed. The third, however, sits at a level a bit less than -30dBc. Could be improved with a low-pass filter stage in the output matching network. We can taks a wider view of the spectrum to look for VHF ringing.




There are a large number of harmonics visible. However, they are all below -40dBc (with the exception of the third harmonic). This is good given the “brutal” look of the drain voltage.

Efficiency as a function of frequency

We will use the so-called power-added-efficiency, which takes into account the DC (drain) efficiency as well as the RF input to the amplifier:

PAE = PRFout / (Pdc+ PRFin)

By keeping everything the same and shifting the frequency up and down by 5% yields

Frequency (MHz)

Power output (watts)

Transistor dissipation (W)

Efficiency %

4.28

269

59.5

82

4.5

309

20.3

94

4.73

199

8.18

96



Below the ideal frequency, the drain loading begins to look capacitive. The drain voltage lags a bit and causes a bit more overlap with the drain current (and hence, transistor dissipation). Slightly raising the frequency above the design frequency reduces the output power, but the dissipation in the switching element is not adversely effected. In fact, the simulation indicates that the dissipation will decrease. However, the overall efficiency is about the same as for 4.5MHz.

Construction and testing

The circuit for the first generation practical prototype is somewhat different than that shown at the beginning of this page.




This circuit uses the IXYS IXDD414 MOSFET driver as a “driver amplifier” for the MOSFET. A low-level (i.e. 5-V 100mA) input is all that is needed to generate full power on the output. The resistor in the gate circuit is to reduce the possibility of VHF oscillation during switching.



Using the toner transfer method, a printed circuit board is easily constructed using the mirror-image plot of the full-size etching pattern.




Quantity

Description

Supplier number

Price ea (3-2006, EUR)

1

IXDD414CI TO220-5 case

Digikey IXDD414CI-ND

2.34

1

2SK2698 TO247 case

Digikey Part #2SK2698T-ND

1.6

1

RFC wound on 2 stacked ferrite cores.

Digikey Part #240-2139-ND

0.73

1

180pF Mica 500V

Digikey Part #338-1082-ND

1.3

1

1000pF Mica 500V

Digikey Part #338-1044-ND

1.79

1

2200pF Mica 500V

Digikey Part #338-1055-ND

2.95

2

470pF Mica 500V

Digikey Part #338-1089-ND

1.43

2

1 ohm 2W

Local supplier


1

50 ohm 1W

Local Supplier


2

0.47uF polyester 400V

Local Supplier


2

BNC female

Digikey Part #ARF-1099-ND

0.92


Assorted heat sinks, enclosure, hardware, PCB supplies





Picture of the finished amplifier:









Input (top trace, 2V/div) and output signal (bottom trace, 50V/div)




References:

[1] J. F. Davis and D. B. Rutledge, “A low-cost class-E power amplifier with sine-wave drive,” IEEE MTT-S Int. Microwave Symp. Dig., vol. 2, pp. 1113-1116, Jun. 1998.

[2] http://www.classeradio.com/

See also my updated notes on choosing the component values for class-E operation.

Spice code for amplifier

* This circuit models a class-E 4.5MHz amplifier using a 2SK2698 MOSFET

.INCLUDE w14nm50.cir


LDD 1 2 40uH


*Output matching

VDD 1 0 DC 100.

CDD 2 0 450p

LRNG 2 30 1.72u

CRNG 30 31 2.7n

LTRP 31 32 265n

CTRP 32 0 1.18n

RLD 31 0 50


*Input Ckt.

VDSNS 2 20 DC 0

DDD 0 20 DIODE

XQ1 20 3 0 STW14NM50

XTR1 6 0 3 0 TRANS

CGG 6 7 47p

LGG 6 7 170n

CBYPS 6 10 10p

RBYPS 10 0 4.7

VCUR 7 8 DC 0

RSRC 8 9 50

*BIN 9 0 V=10.0*SIN(6.28e6*v(1000)*0.25*(1.0+1.0e5*v(1000)))

BIN 9 0 V=30.0*SIN(0.95*2.83e7*v(1000))


*TIME BASE

CTB 1000 0 1 IC=0.0

ITB 1000 0 DC -1


.MODEL DIODE D VJ=1.0

.OPTIONS NOPAGE ITL=4 RELTOL=0.000001

.END


.SUBCKT TRANS 1 2 3 4

LT1 1 2 2u

LT2 3 4 0.5u

K12 LT1 LT2 0.95

.ENDS


Model for the 2SK2698 (Courtesy of STMicroelectronics)

* MODELLING FOR STW14NM50 (2SK2698 Cross reference)

* D G S

.SUBCKT STW14NM50 1 2 3

LG 2 4 7.5n

LS 12 3 7.5n

LD 6 1 4.5n

RG 4 5 1.419

RS 9 12 0.149e-1

RD 7 6 0.136

RJ 8 7 0.667e-01

*E3 8 13 POLY(2) 6 8 6 12 0 0 0 0 0.171 **OLD POLY FORMAT**

BDD 8 13 v=0.171*v(6,8)*v(6,12)

CGS 5 9 0.879e-9

CGD 7 10 0.981e-9

CK 11 7 0.206e-10

DGD 11 7 DGD

DBS 12 6 DBS

DBD 9 7 DBD

MOS 13 5 9 9 MOS L=1u W=1u

E1 10 5 101 0 1

E2 11 5 102 0 1

G1 0 100 7 5 1u

D1 100 101 DID

D2 102 100 DID

R1 101 0 1MEG

R2 102 0 1MEG


.MODEL MOS NMOS LEVEL=3 VTO=4.999 PHI=0.631 IS=0.1P JS=0 THETA=0.228 KP=5.001

.MODEL DGD D IS=0.1P CJO=0.219e-10 VJ=0.849 M=0.306

.MODEL DBD D IS=0.1P CJO=0.682e-10 VJ=0.824 M=0.387

.MODEL DBS D IS=0.1P BV=544 N=1 TT=0.188e-6 RS=0.798e-1

.MODEL DID D IS=2P RS=0 BV=544


.ENDS STW14NM50

Last updated: 20091023